> I know you all are probably fed up with me but I am begging
> Pat-the pathetic guy who cannot get delay to work


I think that what is happening here, is that your note is 
ending before the delay gets a chance to come around.  You
see that the first note duration is 10, yet the delay signal
would not happen until 30, when the note is already shut off!

I also gather that what you really want is a 'delay' in the
guitar effect sense, which feeds its output back into it's 
input, usually at a slightly lower volume so that the sound
fades out as it repeats.  For this you need the 'delayw/delayr'
pair.

I would make an instr 99 with a global delay:

>>> ORC <<<

sr      = 44100
kr      = 4410
ksmps   = 10
nchnls  = 1

                gaSig           init            0

instr 1
                iFront          init            p3 * .1
                iBack           init            p3 * .2
                iMid            init            p3 - (iFront + iBack)

                aEnv            linseg          0, iFront, 1, iMid, 1, iBack, 0
                aSig            oscil           p4 * aEnv, p5, 1

                gaSig           =               gaSig + aSig
endin


                ;***** GLOBAL DELAY INSTRUMENT *****
instr 99
                kDelaydecay     init            .8
                iDelaytime      init            1.3

                aSig            delayr          iDelaytime
                                delayw          kDelaydecay * (gaSig + aSig)
                                out             aSig + gaSig

                gaSig           =               0
endin


>>> SCO <<<


f1 0 65536 10 1 .6 .3 .1
i1 0 .5 10000 220
i1 .2 .2 10000 404
i1 .6 .4 10000 344
i99 0 30
            


>>> END <<<




Toby