Greetings all

I would attempt this myself, but I am very new to CSound....does anyone
have a .orc that simulates a Digeridoo, that they would be willing to
give me? Or any insights for coding one such a file?

Many thanks.


--


6669the RaabidMuttn Speaks6999

>From my archives....




; This patch generates the sound of a didjerido 
; by means of wave shaping....

;	Michel Peters
; Utrecht School of the Arts
; dep. Musictechnology
; course year MT-t-1  94/95

sr=44100                                                      
kr=441
ksmps=100
nchnls=2

		instr	1

;=======ENVELOPES====================================================
kenv1	linseg	0, .1*p3, 1, .8*p3, 1, p3*.1,	0 ;/--\(FADE IN/OUT)

;=======LFO'S========================================================
klfo1	randi	.02,	20,	.123
klfo2	randi	.02,	10,	.23
klfo3	randi	500,	5,	.67
;=======SIGNAL-PROCESSING============================================
anoise	rand	.05			            ;NOISE
asin1	oscili	.3+klfo2,	p5+klfo1,	1	;FREQ+LFO'S
awave1	tablei	asin1,		2,	1,	.5	;WAVESHAPING/SQA.+RES.
afilter	reson	awave1+anoise,1000,	1000+klfo3
abal	balance	afilter,awave1
;=======OUTPUT=======================================================
		outs	abal*kenv1*p4,abal*kenv1*p4
		endin


;========================================================SCORE=======
; a test-score for the wave shaped didge

f1 0 1024 10 1
f2 0 1024 7 0 32 1 32 .7 64 .9 54 .6 64 1 54 .7 64 1 44 .8 84 .6 40 -.6 84 -.8 
44 -1 64 -.7 54 -1 64 -.6 54 -.9 64 -.7 32 -1 32 0

;instr	 start	 dur	 amp	  freq
i1       0       5       29000     65
e