Thomas Huber  wrote:

> Does anyone have a good sounding rim shot ? I tried to mix
> a lower (~300Hz) and a higher (~5kHz) frequency 
> oscillator, 

This is a simple fm-based instrument, sounds similar to
the rim shot sound of the tr-808.


-------- rimshot.orc --------

sr      =  44100
kr      =  44100
ksmps   =  1
nchnls  =  1

/* simple FM-based rimshot instrument */
/* coded by Istvan Varga, Nov 9 1999  */

        seed 0

        instr 1

p3      =  p3 + 0.1

/* base frequency */

icps    =  440.0*exp(log(2.0)*(57.0-69.0)/12.0)
kcps    port icps, 0.0025, icps*2.0

iamp    =  0.0039 + p4*p4/16192.0       /* velocity */

k1a     phasor kcps, 0.0        /* square wave */
k1b     phasor kcps, 0.5

kfmenv  expon 1.0, 0.02, 0.5    /* FM envelope */

k1      =  (k1a-k1b)*6.0*kfmenv
kcps    =  kcps*(1.0+k1)

a0      oscil3 1.0, kcps, 1     /* sine oscillator */

a1      unirand 2.0             /* add some noise */
a1      tone a1-1.0, 2000
a0      =  a0 + a1*0.1

aenv    expon 1.0, 0.005, 0.5   /* amp. envelope */

/* distortion */

a0      limit 4.0*iamp*a0*aenv, -1.0, 1.0
a0      table3 a0*4096.0, 1, 0, 0, 1

/* lowpass filter freq. envelope */

kffrq   expseg 20000, 0.07, 100, 1, 100

a0x     tone a0, 4000
a0y     =  a0 - a0x
a0x     delay a0y, 0.0002
a0      =  a0 - a0x*4.0
a0      butterlp a0, kffrq

/* de-click envelope */

a_      linseg 1, p3-0.1, 1, 0.025, 0, 1, 0
a0      =  a0*a_

        out a0*12500

        endin

-------- rimshot.sco --------

t 0 120

/* p4 = velocity */

i 1      0.000  0.5000  120
i 1      0.500  0.5000  120
i 1      1.000  0.5000  120
i 1      1.500  0.5000  120

i 1      4.000  0.2500  40
i 1      +      .       <
i 1      +      .       <
i 1      +      .       <

i 1      +      .       <
i 1      +      .       <
i 1      +      .       <
i 1      +      .       <

i 1      +      .       <
i 1      +      .       <
i 1      +      .       <
i 1      +      .       <

i 1      +      .       <
i 1      +      .       <
i 1      +      .       <
i 1      +      .       <

i 1      8.000  0.5000  127

f 1 0 16384 10 1        /* sine wave */

e

-------- rimshot.orc.gz --------

begin-base64 644 rimshot.orc.gz
H4sICOimKDgCA3JpbXNob3Qub3JjAGVTTXPaMBA9279ij6BgI4Eh40Ovmekh
PfaaEbYAjWVJWDKBf99diaZNMsOYlfbpfazlMBU/AJpGcF4O/9dh9IGWorTd
2ZpHXa4ZBD16o+DltTrIoHqY9BjOLoK2IU7zqGwEtiZg53psH+7wM8SrtPBb
Tie5gl/uCi2Itm2BgGURFMI4FomBVPyW5PwWnoDXWZW04Dipy6xsd08HdZct
Ng2vOVM3vzDutNjUfMkWu+eaV/sW67WgnXIgsHcT+sRqhbycb3artGKIQDo5
eqKjzrZFad8w36zFXrTYL9DDVRnX6ZjVByELf5bBTTD8ZSRQuMxyUvAur4pw
gzh8he3w8BHndC3Qs7Mgap5Ob1KTOF5eAduo5tVDi4wtULJCviXbY95MkXNh
k/7ZAqmeBrEsS8kLFzpttpk9S4vkT1sFqWdkRFfEL0UxWz1J2wNFJZjsewhu
VGCdDskFgqLDs1JUiXPD8Z6gDopLjuOSgqWXJb8n47uPaDjk+nM43Ox1QCtR
45FkhxdGjzpCgznptTDJGdGuIEvjg0BRHozaojpreLtPDdRJv3xpjHv3MgQ4
ahPVlK7PF/HheJwu5DaoU0qUDT8jA8989DWg2O0RHjebHPz+SF7h45YQvTLy
jqt7Ds03/8aTQKzJvg9zRDvGJ7bkIE9BVZ3R3fDZoXzDYViyh2b8tsIZ55x1
ur+P0B9KTL7hl+TmSLXY7Mh9oWyvbVmWfwCLlvl+7gMAAA==
====

-------- rimshot.sco.gz --------

begin-base64 644 rimshot.sco.gz
H4sICP2mKDgCA3JpbXNob3Quc2NvAOMqUTBQMDQy4OLS11IoMFGwVShLzclP
ziypVNDS5+LKVDDkVDDQMzAw4DTQMwVRILVQUVMsooZY1Rqiq4UIm0AVG4Fk
TaBqtTn1OG1wMAmroKNiC1SvmnNxpSkYgkLTzNjCRMEQyOAEhmlxZl6qQnli
WSo4PFO5uLgAamcbP3MBAAA=
====

--------------------------------



--