| Hi,
What is music?
It ain't got a thing if it ain't got that swing.
but I get a kick out of corn!
Actually my two major endeavors in music are blues harmonica improvisation
which lets me really get into the music and electronic/synthesizer and
computer music which lets me try to be really creative and innovative.
Anyway I wrote out some examples to go with my earlier post. They could
use some DC blocking...
; ORCHESTRA
sr=22050
kr=2205
ksmps=10
nchnls=2
; Orbits Traced on Complex 3D Surfaces
; z=sin^2*(sqrt(x^2+y^2))
instr 1
idur = p3
iamp = p4
ifqc = cpspch(p5)
kdclick linseg 0, .002, iamp, idur-.004, iamp, .002, 0
krsize linseg .5, idur*.5, 5, idur*.5, .5 ; Sweeps both radius size and
circle center
krad0 oscil krsize, 1, 1
krad1 = krad0+6 ; Make a positive radius.
ax0 oscil krad1, ifqc, 1, .25 ; Cosine
ax = ax0+krsize
ay0 oscil krad1, ifqc, 1 ; Sine
ay = ay0-krsize
az1 = sin(sqrt(ax*ax+ay*ay)) ; Compute the surface
az = az1*az1-.5
outs az*kdclick, az*kdclick
endin
; z=ln(x^2+y^2)
instr 2
idur = p3
iamp = p4
ifqc = cpspch(p5)
kdclick linseg 0, .002, iamp, idur-.004, iamp, .002, 0
krsize linseg .5, idur*.5, 5, idur*.5, .5
krad0 oscil krsize, 1, 1
krad1 = krad0+6
ax0 oscil krad1, ifqc, 1, .25 ; Cosine
ax = ax0+krsize
ay0 oscil krad1, ifqc, 1 ; Sine
ay = ay0-krsize
az = log(ax*ax+ay*ay)-4
outs az*kdclick, az*kdclick
endin
; z=-5*x/(x^2+y^2+1)
instr 3
idur = p3
iamp = p4
ifqc = cpspch(p5)
kdclick linseg 0, .002, iamp, idur-.004, iamp, .002, 0
krsize linseg .5, idur*.5, 5, idur*.5, .5
krad0 oscil krsize, 1, 1
krad1 = krad0+6
ax0 oscil krad1, ifqc, 1, .25 ; Cosine
ax = ax0+krsize
ay0 oscil krad1, ifqc, 1 ; Sine
ay = ay0-krsize
az = -5*ax/(ax*ax+ay*ay+1)
outs az*kdclick, az*kdclick
endin
; SCORE
f1 0 8192 10 1
; Sta Dur Amp Pch
i1 0 2 20000 8.00
i2 2 2 1000 8.00
i3 4 2 5000 8.00
|