|
Here are some bass drums for those who want to use them in
techno songs
------------------------ bd5000a.orc ------------------------
sr = 44100
kr = 22050
ksmps = 2
nchnls = 1
instr 1
ivol = 2.0 /* volume */
ibpm = 140.00 /* tempo */
irel = 0.1667 /* release time */
ifrq0 = 5.3333 /* start freq. / note frq. */
ifrqe = 14.000 /* freq. env. speed */
i001 = 1/65536
ivel = 0.0039+p5*p5/16192 /* velocity */
ibtime = 60/ibpm /* beat time */
ivol = ivel*ivol
icps0 = 440.0*exp(log(2.0)*(p4-69.0)/12.0) /* freq. */
p3 = p3 + irel + 0.1
/* osc. */
kcps expseg ifrq0-1,ibtime/ifrqe,(ifrq0-1)*0.5
kcps = (kcps+1)*icps0
knumh = sr/(2*kcps)
a_ buzz sr/(20*3.14159265), kcps, knumh, 256, 0.25
a__ buzz sr/(20*3.14159265), kcps, knumh, 256, 0.75
aosc0 tone a_-a__, 20
aosc1 = aosc0*1.0
aoscn unirand 2
aoscn = (aoscn-1)*1.0
kffrq port icps0, ibtime/8, icps0*ifrq0 /* OSC. 1 */
aosc1 butterlp aosc1, kffrq
ax1 = aosc1
aoscn butterbp aoscn, 8372, 8372 /* noise */
kffrq port 65.4, ibtime/16, 2093
aoscn butterlp aoscn, kffrq
axn = aoscn
kenv1l linseg -0.25, 0.00275, -0.25, 0.00001, 1.0, 1, 1.0
kenv1e expseg 1, 1, 0.001, 1, 0.001
kenvx expseg 1, p3-(irel+0.1), 1, irel, 1/1024
aenv1 interp kenv1l*kenv1e
aenvx interp kenvx*ivol
ax0 = ax1*aenv1
ax0 pareq ax0, 65.4, 2.25, 1.5, 0 /* OUTPUT EQ */
ax0 butterlp ax0, 4186
a0x = (ax0+axn)*aenvx
out -7000*a0x
endin
------------------------- bd5000a.sco -----------------------
t 0 140.000 /* tempo */
i 1 0.000 0.4000 31 120
i 1 1.000 0.4000 31 120
i 1 2.000 0.4000 31 120
i 1 3.000 0.4000 31 120
f 256 0 262144 10 1
e /* END OF SCORE */
------------------------ bd16_01.orc ------------------------
sr = 44100
kr = 22050
ksmps = 2
nchnls = 1
/* ------------------------------------------------------- */
seed 0
instr 1
imkey = p4 /* get note parameters from score file */
imvel = p5
icps = 440.0*exp(log(2.0)*(imkey-69.0)/12.0)
iamp = 0.0039+imvel*imvel/16192
/* ------------------------------------------------------- */
ivol = 5500 /* output volume */
ibpm = 135 /* tempo */
ifrqs = 5.3333 /* osc. start frq. / note freq. */
ifrqe = 1.0 /* osc. end freq. / note frq. */
ifrqd = 16 /* osc. freq. envelope speed */
iffr1s = 880 /* LP filter start freq. 1 (Hz) */
iffr1d = 128 /* LP filter frq. 1 decay speed */
iffr2s = 0 /* LP filter start freq. 2 (Hz) */
iffr2d = 1 /* LP filter frq. 2 decay speed */
iffr3s = 8 /* LP filter start freq. 3 / note frq. */
iffr3d = 8 /* lowpass filter freq. 3 decay speed */
iffr4s = 0 /* LP filter start freq. 4 / note frq. */
iffr4d = 1 /* lowpass filter freq. 4 decay speed */
iEQ1fo = 0.5 /* EQ 1 frequency / osc. freq. */
iEQ1fn = 0 /* EQ 1 frequency / note freq. */
iEQ1fa = 0 /* EQ 1 frequency (Hz) */
iEQ1l = 0.25 /* EQ 1 level */
iEQ1q = 0.7071 /* EQ 1 Q */
iEQ1m = 1 /* EQ 1 mode (0:peak,1:lo,2:hi) */
iEQ2fo = 0.5 /* EQ 2 frequency / osc. freq. */
iEQ2fn = 0 /* EQ 2 frequency / note freq. */
iEQ2fa = 0 /* EQ 2 frequency (Hz) */
iEQ2l = 0.25 /* EQ 2 level */
iEQ2q = 0.7071 /* EQ 2 Q */
iEQ2m = 1 /* EQ 2 mode (0:peak,1:lo,2:hi) */
iEQ3fo = 0.5 /* EQ 3 frequency / osc. freq. */
iEQ3fn = 0 /* EQ 3 frequency / note freq. */
iEQ3fa = 0 /* EQ 3 frequency (Hz) */
iEQ3l = 4 /* EQ 3 level */
iEQ3q = 2.0 /* EQ 3 Q */
iEQ3m = 0 /* EQ 3 mode (0:peak,1:lo,2:hi) */
iEQ4fo = 0 /* EQ 4 frequency / osc. freq. */
iEQ4fn = 1.5 /* EQ 4 frequency / note freq. */
iEQ4fa = 0 /* EQ 4 frequency (Hz) */
iEQ4l = 2.0 /* EQ 4 level */
iEQ4q = 1.0 /* EQ 4 Q */
iEQ4m = 0 /* EQ 4 mode (0:peak,1:lo,2:hi) */
insmix = 16 /* noise mix */
iEQn1fo = 0 /* noise EQ 1 frequency / osc. freq. */
iEQn1fn = 1 /* noise EQ 1 frequency / note freq. */
iEQn1fa = 0 /* noise EQ 1 frequency (Hz) */
iEQn1l = 0.0625 /* noise EQ 1 level */
iEQn1q = 0.7071 /* noise EQ 1 Q */
iEQn1m = 1 /* noise EQ 1 mode (0:peak,1:lo,2:hi) */
iEQn2fo = 0 /* noise EQ 2 frequency / osc. freq. */
iEQn2fn = 16 /* noise EQ 2 frequency / note freq. */
iEQn2fa = 0 /* noise EQ 2 frequency (Hz) */
iEQn2l = 0.0625 /* noise EQ 2 level */
iEQn2q = 0.7071 /* noise EQ 2 Q */
iEQn2m = 1 /* noise EQ 2 mode (0:peak,1:lo,2:hi) */
/* ------------------------------------------------------- */
p3 = p3+0.15 /* increase note length */
ibtime = 60/ibpm
/* amp. envelope */
kamp linseg 1, p3-0.15, 1, 0.05, 0, 0.1, 0
kamp = kamp*iamp*ivol
/* kcps = osc. frequency, knumh = num. of harmonics */
kcps port ifrqe*icps, ibtime/ifrqd, ifrqs*icps
knumh = sr/(2*kcps)
/* oscillator */
a_ buzz sr/(3.14159265*10), kcps, knumh, 1, 0
a__ buzz sr/(3.14159265*10), kcps, knumh, 1, 0.5
a0 tone a_-a__,10
a_ unirand 2 /* noise generator */
a_ = a_-1
a_ pareq a_, iEQn1fa+icps*iEQn1fn+kcps*iEQn1fo, \
iEQn1l, iEQn1q, iEQn1m
a_ pareq a_, iEQn2fa+icps*iEQn2fn+kcps*iEQn2fo, \
iEQn2l, iEQn2q, iEQn2m
a0 = a0 + insmix*a_
/* EQ */
a0 pareq a0, iEQ1fa+icps*iEQ1fn+kcps*iEQ1fo, iEQ1l, \
iEQ1q, iEQ1m
a0 pareq a0, iEQ2fa+icps*iEQ2fn+kcps*iEQ2fo, iEQ2l, \
iEQ2q, iEQ2m
a0 pareq a0, iEQ3fa+icps*iEQ3fn+kcps*iEQ3fo, iEQ3l, \
iEQ3q, iEQ3m
a0 pareq a0, iEQ4fa+icps*iEQ4fn+kcps*iEQ4fo, iEQ4l, \
iEQ4q, iEQ4m
/* filter freq. envelopes */
kffr1 port 0, ibtime/iffr1d, iffr1s
kffr2 port 0, ibtime/iffr2d, iffr2s
kffr3 port 0, ibtime/iffr3d, iffr3s*icps
kffr4 port 0, ibtime/iffr4d, iffr4s*icps
/* kffrq = LP filter frequency */
kffrq = kffr1 + kffr2 + kffr3 + kffr4
a0 butterlp a0, kffrq /* LP filter */
a_ = a0*kamp
out a_
endin
-------------------------- bd16_01.sco ----------------------
t 0 135.00 /* tempo */
i 1 0.0000 0.4000 33 120
i 1 1.0100 0.4000 33 112
i 1 2.0100 0.4000 33 124
i 1 3.0050 0.4000 33 112
i 1 4.0000 0.4000 33 116
i 1 5.0100 0.4000 33 112
i 1 6.0100 0.4000 33 120
i 1 6.9900 0.3000 33 120
i 1 7.5000 0.3000 33 116
i 1 8.0000 0.4000 33 120
i 1 9.0100 0.4000 33 112
i 1 10.010 0.4000 33 124
i 1 11.005 0.4000 33 112
i 1 12.000 0.4000 33 116
i 1 13.010 0.4000 33 112
i 1 14.010 0.4000 33 120
i 1 15.005 0.4000 33 112
/* ------------------------------------------------------- */
f 1 0 262144 10 1
e /* end of score */
-------------------------------------------------------------
Received: from wallace.maths.bath.ac.uk by omphalos.maths.Bath.AC.UK id aa00207;
23 Sep 99 15:34 BST
Received: from [144.173.6.14] (helo=exeter.ac.uk)
by wallace.maths.bath.ac.uk with esmtp (Exim 2.12 #1)
id 11U90R-0005MT-00
for jpff@maths.bath.ac.uk; Thu, 23 Sep 1999 14:33:51 +0100
Received: from noether [144.173.8.10] by hermes via SMTP (PAA225913); Thu, 23 Sep 1999 15:30:38 +0100 (BST)
Received: from exeter.ac.uk by maths.ex.ac.uk; Thu, 23 Sep 1999 15:30:20 +0100
Received: from fm2.freemail.hu [194.38.105.12] by hermes via SMTP (PAA218451); Thu, 23 Sep 1999 15:30:18 +0100 (BST)
Received: (qmail 13532 invoked by uid 339175); 23 Sep 1999 14:30:09 -0000
Date: 23 Sep 1999 14:30:09 -0000
Message-ID: <19990923143009.13527.qmail@freemail.c3.hu>
MIME-Version: 1.0
To: csound@maths.ex.ac.uk
Subject: Yet another bassdrum :)
From: =?ISO-8859-2?Q?Varga_Istv=E1n?=
Sender: owner-csound-outgoing@maths.ex.ac.uk
Precedence: bulk
------------------------- bd4004m.orc -----------------------
sr = 44100
kr = 44100
ksmps = 1
nchnls = 1
/* convert MIDI note number to frequency */
#define MIDI2CPS(xmidikey)
# (440.0*exp(log(2.0)*(($xmidikey)-69.0)/12.0)) #
/* convert frequency to MIDI note number */
#define CPS2MIDI(xfreqcps)
# (12.0*(log(($xfreqcps)/440.0)/log(2.0))+69.0) #
/* convert velocity to amplitude */
#define VELOC2AMP(xvelocity)
# (0.0039+(($xvelocity)*($xvelocity))/16192.0) #
/* convert amplitude to velocity */
#define AMP2VELOC(xamplitude)
# (sqrt((($xamplitude)-0.0039)*16192.0)) #
seed 0
instr 1
kgoto start01
/*-------------------------------------------------------- */
ivol = 0.6 /* volume */
ibpm = 140.0 /* tempo */
irel = 0.1667 /* release time (sec.) */
idel = 0.02 /* delay time */
imod0 = 0.0025 /* random mod. of delay (sec.) */
imod1 = 0.005 /* rnd. mod. of velocity */
if01 = 5.3333 /* osc. start frequency (rel.) */
ifd1 = 14.0 /* freq. envelope decay speed */
ibw01 = 0.5 /* OSC1 BP bandwidth (rel.) */
ihp1 = 0.0625 /* OSC1 HP frequency (rel.) */
iapf1 = 1.0 /* OSC1 allp. flt. start freq. (rel.) */
iapf2 = 1.0 /* OSC1 allp. flt. end freq. */
iapdx = 8 /* OSC1 allp. flt. envelope speed */
ifr3 = 8 /* OSC2 HP1 freq. / base frq. */
imx3 = -5 /* OSC2 HP1 mix */
ifr4 = 0.5 /* OSC2 output HP f. / note f. */
imx2 = -0.4 /* OSC2 output gain */
ihp2 = 1.5 /* output HP frq. / note f. */
ibw02 = 2.0 /* output HP resonance */
ifr1 = 8 /* out. LP start f. 1 / note f. */
ifdx1 = 8 /* out. LP freq. 1 env. speed */
ifr2 = 8 /* out. LP start f. 2 / note f. */
ifdx2 = 8 /* out. LP freq. 2 env. speed */
ifxBP1 = 7040 /* noise BP start frq. (Hz) */
ifxBP2 = 7040 /* noise BP end frequency */
ibw1 = 2 /* noise BP bandwidth/freq. */
ifxLP1 = 3520 /* noise LP start frq. (Hz) */
ifxLP2 = 55 /* noise LP end frequency */
ifxd = 12 /* noise filter envelope speed */
iattn1 = 0.01 /* noise attack time (sec.) */
idecn1 = 3 /* noise decay speed */
imxn = 0.6 /* noise mix */
/* ------------------------------------------------------- */
i001 = 1/65536
imkey = p4 /* note number */
imvel = p5 /* velocity */
ivel = $VELOC2AMP(imvel) /* convert velocity */
im0 unirand 2
im1 unirand 2
ivel = ivel*(1+(im1-1)*imod1) /* rand. veloc. */
idel = idel+((im0-1)*imod0) /* rand. delay */
ibtime = 60/ibpm /* beat time */
i002 = exp(log(i001)*(idel+irel+16/kr)/irel)
ivol = ivel*ivol
icps = $MIDI2CPS(imkey) /* base freq. */
ifmax = sr*0.48 /* max. allowed freq. */
ihp2 = ihp2*icps
ibw02x = ihp2/ibw02
ifxLP2 = ifxLP2-ifxLP1
ifxBP2 = ifxBP2-ifxBP1
iapf2 = iapf2-iapf1
ixtime = (irel+idel+16/kr)
p3 = p3+ixtime /* increase note length */
start01:
kenvn1 expseg 1,ibtime/idecn1,0.5 /* noise generator */
kenvn2 linseg 0,iattn1,1,1,1
aenvn interp kenvn1*kenvn2
kenvn3 expseg 1,ibtime/ifxd,0.5
kenvn3 = (1-kenvn3)
kfxBPf = ifxBP1+(kenvn3*ifxBP2)
a1l unirand 2
a1l butterbp imxn*32768*(a1l-1)*aenvn,kfxBPf,kfxBPf*ibw1
a1l butterlp a1l,ifxLP1+(ifxLP2*kenvn3)
/* envelopes */
kamp1 expseg 1,p3-ixtime,1,ixtime,i002
kfrq1 expseg 1,ibtime/ifd1,0.5
kfrq = icps*(1+kfrq1*(if01-1))
kapfr expseg 1,ibtime/iapdx,0.5
kapfr = kfrq*(iapf1+iapf2*(1-kapfr))
kfrx1 expseg 1,ibtime/ifdx1,0.5
kfrx2 expseg 1,ibtime/ifdx2,0.5
kfrx = kfrq*(kfrx1*ifr1+kfrx2*ifr2)
kfrx = (kfrx>ifmax ? ifmax : kfrx)
/* kfrq = osc. frequency, kapfr = allpass filter frequency */
/* kfrx = LP filter frequency */
/* oscillator */
knumh = sr/(2*kfrq)
a1 buzz sr/(10*3.14159265), kfrq, knumh, 256, 0.25
a2 buzz sr/(10*3.14159265), kfrq, knumh, 256, 0.75
a1 tone (a1-a2)*16384, 10
a2 = a1 /* a1 = a2 = osc. signal */
a1 butterhp a1,kfrq*ihp1 /* filters */
a1 butterbp a1,kfrq,kfrq*ibw01
a1x tone a1,kapfr
a1 = 2*a1x-a1
a3 butterhp a2,kfrq*ifr3
a2 = a2+a3*imx3
a2 butterhp a2,kfrq*ifr4
a0x = a2*imx2+a1
atmp butterbp a0x*ibw02,ihp2,ibw02x
a0x butterhp a0x+atmp,ihp2
a0x butterlp a0x,kfrx
a0y delay (a0x+a1l)*ivol*kamp1,idel
out a0y
endin
--------------------------- bd4004m.sco ---------------------
t 0.00 140.000 /* tempo */
#define rhytm1(STIME) #
i 1 [$STIME+0.0000] 0.4375 33 120
i 1 [$STIME+0.9900] 0.4375 33 112
i 1 [$STIME+1.9900] 0.4375 33 124
i 1 [$STIME+2.9950] 0.4375 33 112
i 1 [$STIME+4.0000] 0.4375 33 116
i 1 [$STIME+4.9900] 0.4375 33 112
i 1 [$STIME+5.9900] 0.4375 33 116
i 1 [$STIME+6.9950] 0.4000 33 112
#
$rhytm1(0)
$rhytm1(8)
i 1 15.5 0.4 33 116
/* ------------------------------------------------------- */
f 256 0 262144 10 1
e /* end of score */
-------------------------------------------------------------
Received: from shaun.maths.bath.ac.uk by omphalos.maths.Bath.AC.UK id aa00220;
23 Sep 99 15:35 BST
Received: from [144.173.6.14] (helo=exeter.ac.uk)
by shaun.maths.bath.ac.uk with esmtp (Exim 2.12 #1)
id 11U9y4-0003ls-00
for jpff@maths.bath.ac.uk; Thu, 23 Sep 1999 15:35:28 +0100
Received: from noether [144.173.8.10] by hermes via SMTP (PAA221761); Thu, 23 Sep 1999 15:32:07 +0100 (BST)
Received: from exeter.ac.uk by maths.ex.ac.uk; Thu, 23 Sep 1999 15:31:56 +0100
Received: from fm2.freemail.hu [194.38.105.12] by hermes via SMTP (PAA218959); Thu, 23 Sep 1999 15:31:55 +0100 (BST)
Received: (qmail 15606 invoked by uid 339175); 23 Sep 1999 14:31:53 -0000
Date: 23 Sep 1999 14:31:53 -0000
Message-ID: <19990923143153.15605.qmail@freemail.c3.hu>
MIME-Version: 1.0
To: csound@maths.ex.ac.uk
Subject: Linseg (k-rate) and tone bugs
From: =?ISO-8859-2?Q?Varga_Istv=E1n?=
Sender: owner-csound-outgoing@maths.ex.ac.uk
Precedence: bulk
------------------------- test1.orc -------------------------
sr = 44100
kr = 44100
ksmps = 1
nchnls = 1
instr 1
afoo = 10000
kbar linseg 1, 0.5, 1, 0.0005, 0, 1, 0 /* BUGGY */
ablah linseg 1, 0.5, 1, 0.0005, 0, 1, 0
;afoo = afoo*ablah /* this works */
afoo = afoo*kbar /* envelope will not reach zero */
/* in the second segment */
out afoo
endin
--------------------- test1.sco -----------------------------
t 0 60
i 1 0 1
e
--------------------- test2.orc -----------------------------
sr = 44100
kr = 1050
ksmps = 42
nchnls = 1
seed 0
instr 1
afoobar unirand 2 /* white noise */
afoobar = afoobar-1
;afoo tone afoobar, 2 /* this works well */
afoo tone afoobar, 1 /* outputs silence */
out afoo*1000000
endin
--------------------- test2.sco -----------------------------
t 0 60
i 1 0 2
e
-------------------------------------------------------------
Received: from shaun.maths.bath.ac.uk by omphalos.maths.Bath.AC.UK id aa00309;
23 Sep 99 16:27 BST
Received: from [144.173.6.14] (helo=exeter.ac.uk)
by shaun.maths.bath.ac.uk with esmtp (Exim 2.12 #1)
id 11UAlz-0003n4-00
for jpff@maths.bath.ac.uk; Thu, 23 Sep 1999 16:27:03 +0100
Received: from noether [144.173.8.10] by hermes via SMTP (QAA234549); Thu, 23 Sep 1999 16:22:31 +0100 (BST)
Received: from exeter.ac.uk by maths.ex.ac.uk; Thu, 23 Sep 1999 16:22:17 +0100
Received: from fm2.freemail.hu [194.38.105.12] by hermes via SMTP (QAA236172); Thu, 23 Sep 1999 16:22:16 +0100 (BST)
Received: (qmail 2672 invoked by uid 339175); 23 Sep 1999 15:22:05 -0000
Date: 23 Sep 1999 15:22:05 -0000
Message-ID: <19990923152205.2671.qmail@freemail.c3.hu>
MIME-Version: 1.0
To: csound@maths.ex.ac.uk
Subject: Re: Csound addresses
From: =?ISO-8859-2?Q?Varga_Istv=E1n?=
Sender: owner-csound-outgoing@maths.ex.ac.uk
Precedence: bulk
rasmus ekman wrote:
> Ok, sorry for disinformation then...
> Hasn't worked for two weeks for me, and doesn't now.
> Gets to "Contacting host: (host):(port numbers)" then times out.
> But it's a lot better that I'm wrong here...
Netscape and IE doesn't work for me too, but I can download files
from this site with FAR manager (rather interesting ...)
Received: from wallace.maths.bath.ac.uk by omphalos.maths.Bath.AC.UK id aa01208;
23 Sep 99 21:39 BST
Received: from [144.173.6.14] (helo=exeter.ac.uk)
by wallace.maths.bath.ac.uk with esmtp (Exim 2.12 #1)
id 11UEhw-0005bu-00
for jpff@maths.bath.ac.uk; Thu, 23 Sep 1999 20:39:08 +0100
Received: from noether [144.173.8.10] by hermes via SMTP (VAA261791); Thu, 23 Sep 1999 21:35:59 +0100 (BST)
Received: from exeter.ac.uk by maths.ex.ac.uk; Thu, 23 Sep 1999 21:35:46 +0100
Received: from goose.prod.itd.earthlink.net [207.217.120.18] by hermes via ESMTP (VAA259718); Thu, 23 Sep 1999 21:35:45 +0100 (BST)
Received: from [209.246.91.84] (dialup-209.246.91.84.NewYork2.Level3.net [209.246.91.84])
by goose.prod.itd.earthlink.net (8.9.3/8.9.3) with ESMTP id NAA07070
for ; Thu, 23 Sep 1999 13:35:42 -0700 (PDT)
Message-Id: <199909232035.NAA07070@goose.prod.itd.earthlink.net>
X-Mailer: Microsoft Outlook Express Macintosh Edition - 4.5 (0410)
Date: Thu, 23 Sep 1999 16:42:57 -0400
Subject: test please ignore
From: Eloy Anzola
To: csound@maths.ex.ac.uk
Mime-version: 1.0
X-Priority: 3
Content-type: text/plain; charset="US-ASCII"
Content-transfer-encoding: 7bit
Sender: owner-csound-outgoing@maths.ex.ac.uk
Precedence: bulk
test please ignore
Received: from wallace.maths.bath.ac.uk by omphalos.maths.Bath.AC.UK id aa02192;
24 Sep 99 7:42 BST
Received: from [144.173.6.14] (helo=exeter.ac.uk)
by wallace.maths.bath.ac.uk with esmtp (Exim 2.12 #1)
id 11UO7T-0005sb-00
for jpff@maths.bath.ac.uk; Fri, 24 Sep 1999 06:42:07 +0100
Received: from noether [144.173.8.10] by hermes via SMTP (HAA03432); Fri, 24 Sep 1999 07:40:08 +0100 (BST)
Received: from exeter.ac.uk by maths.ex.ac.uk; Fri, 24 Sep 1999 07:39:56 +0100
Received: from root@bohm.anu.edu.au [150.203.21.88] by hermes via ESMTP (HAA03410); Fri, 24 Sep 1999 07:39:53 +0100 (BST)
Received: from [150.203.14.13] (snagglepuss.anu.edu.au [150.203.14.13])
by bohm.anu.edu.au (8.8.8/8.8.8) with SMTP id QAA10865
for ; Fri, 24 Sep 1999 16:39:36 +1000 (EST)
Date: Fri, 24 Sep 1999 16:39:36 +1000 (EST)
Message-Id: <199909240639.QAA10865@bohm.anu.edu.au>
To: csound@maths.ex.ac.uk
From: Arne Hanna
Subject: THE BOOK
Sender: owner-csound-outgoing@maths.ex.ac.uk
Precedence: bulk
Hi Folks. Anyday now?
Cheers
Arne
Received: from shaun.maths.bath.ac.uk by omphalos.maths.Bath.AC.UK id aa02435;
24 Sep 99 10:19 BST
Received: from [144.173.6.14] (helo=exeter.ac.uk)
by shaun.maths.bath.ac.uk with esmtp (Exim 2.12 #1)
id 11URVl-0004Ew-00
for jpff@maths.bath.ac.uk; Fri, 24 Sep 1999 10:19:25 +0100
Received: from noether [144.173.8.10] by hermes via SMTP (KAA17723); Fri, 24 Sep 1999 10:17:11 +0100 (BST)
Received: from exeter.ac.uk by maths.ex.ac.uk; Fri, 24 Sep 1999 10:16:57 +0100
Received: from front4m.grolier.fr [195.36.216.54] by hermes via ESMTP (KAA17681); Fri, 24 Sep 1999 10:16:56 +0100 (BST)
Received: from club-internet.fr (ppp-160-205.villette.club-internet.fr [195.36.160.205])
by front4m.grolier.fr (8.9.3/No_Relay+No_Spam_MGC990224) with ESMTP id LAA25784
for ; Fri, 24 Sep 1999 11:16:52 +0200 (MET DST)
Message-ID: <37EA7498.F0BE853A@club-internet.fr>
Date: Thu, 23 Sep 1999 20:42:29 +0200
From: JM&M DARREMONT
Reply-To: jmdbrady@club-internet.fr
X-Mailer: Mozilla 4.06 (Macintosh; I; PPC)
MIME-Version: 1.0
To: csound
Subject: Re: Generating scores...
References: <003f01bf05b0$19d47440$0301a8c0@viromet.ro>
Content-Type: text/plain; charset=iso-8859-1
Content-Transfer-Encoding: quoted-printable
X-MIME-Autoconverted: from 8bit to quoted-printable by exeter.ac.uk id KAA17681
Sender: owner-csound-outgoing@maths.ex.ac.uk
Precedence: bulk
Let's know if you make it.=20
I'm very interested and curious about CSound realisations.
Bye.
Radu GRIGOROVICI a =E9crit:
> I would need something like a tracker for csound (with patterns and tra=
cks),
> for simple instrumets. If I have time, I try to write it myself. I hope=
can
> :-)
--=20
Jean-Michel DARREMONT
Received: from wallace.maths.bath.ac.uk by omphalos.maths.Bath.AC.UK id aa02641;
24 Sep 99 10:29 BST
Received: from [144.173.6.14] (helo=exeter.ac.uk)
by wallace.maths.bath.ac.uk with esmtp (Exim 2.12 #1)
id 11UQiU-0005zD-00
for jpff@maths.bath.ac.uk; Fri, 24 Sep 1999 09:28:30 +0100
Received: from noether [144.173.8.10] by hermes via SMTP (KAA19025); Fri, 24 Sep 1999 10:27:02 +0100 (BST)
Received: from exeter.ac.uk by maths.ex.ac.uk; Fri, 24 Sep 1999 10:26:49 +0100
Received: from exim@wallace.maths.bath.ac.uk [138.38.100.104] by hermes via ESMTP (KAA19063); Fri, 24 Sep 1999 10:26:49 +0100 (BST)
Received: from [138.38.99.25] (helo=maths.Bath.AC.UK ident=mmdf)
by wallace.maths.bath.ac.uk with smtp (Exim 2.12 #1)
id 11UQg2-0005yw-00
for csound@maths.ex.ac.uk; Fri, 24 Sep 1999 09:25:58 +0100
Date: Fri, 24 Sep 99 10:26:48 BST
From: jpff@maths.bath.ac.uk
Subject: Re: Linseg (k-rate) and tone bugs
To: csound@maths.ex.ac.uk
Message-Id:
Sender: owner-csound-outgoing@maths.ex.ac.uk
Precedence: bulk
Message written at 24 Sep 1999 09:01:10 +0100
--- Copy of mail to f00f@freemail.hu ---
In-reply-to: <19990923143153.15605.qmail@freemail.c3.hu> (message from
=?ISO-8859-2?Q?Varga_Istv=E1n?= on 23 Sep 1999 14:31:53 -0000)
References: <19990923143153.15605.qmail@freemail.c3.hu>
I *think* the k-rate linseg not going to zero is a fence=post effect;
it has run out of segments and so it repeats the last value which is
the value at teh start of the previosu k-rate. However testing this
hypothesis has given a problem as my test version gives totally
incorrect answers to the orchestra (while the production one has the
fence-post problem.
Oh dear!
==John ffitch |