Do somebody have the tables for a bell-like sound ( by
gen's)
or by additive synthesys. I have seen the propriety
somowhere but I don't remember where.
If you have ther way or making them it will be
helpfull

thanks

Nicolas


	

	
		
___________________________________________________________________________ 
Nouveau : téléphonez moins cher avec Yahoo! Messenger ! Découvez les tarifs exceptionnels pour appeler la France et l'international.
Téléchargez sur http://fr.messenger.yahoo.com

http://music.nuim.ie/musictec/docs/synth/additive.pdf

Thanks Victor!

Drweski nicolas wrote:
> Do somebody have the tables for a bell-like sound ( by
> gen's)
> or by additive synthesys. I have seen the propriety
> somowhere but I don't remember where.
> If you have ther way or making them it will be
> helpfull
> 
> thanks
> 
> Nicolas
> 
> 
> 	
> 
> 	
> 		
> ___________________________________________________________________________ 
> Nouveau : téléphonez moins cher avec Yahoo! Messenger ! Découvez les tarifs exceptionnels pour appeler la France et l'international.
> Téléchargez sur http://fr.messenger.yahoo.com

No! thanks, J C Risset...

At 17:27 09/03/2006, you wrote:
>http://music.nuim.ie/musictec/docs/synth/additive.pdf
>
>Thanks Victor!
>
>Drweski nicolas wrote:
>>Do somebody have the tables for a bell-like sound ( by
>>gen's)
>>or by additive synthesys. I have seen the propriety
>>somowhere but I don't remember where.
>>If you have ther way or making them it will be
>>helpfull
>>thanks
>>Nicolas
>>
>>
>>
>>
>>___________________________________________________________________________ 
>>Nouveau : téléphonez moins cher avec Yahoo! Messenger ! Découvez les 
>>tarifs exceptionnels pour appeler la France et l'international.
>>Téléchargez sur http://fr.messenger.yahoo.com
>--
>Send bugs reports to this list.
>To unsubscribe, send email to csound-unsubscribe@lists.bath.ac.uk

Victor Lazzarini
Music Technology Laboratory
Music Department
National University of Ireland, Maynooth 

Indeed.

Victor Lazzarini wrote:
> No! thanks, J C Risset...
> 
> At 17:27 09/03/2006, you wrote:
>> http://music.nuim.ie/musictec/docs/synth/additive.pdf
>>
>> Thanks Victor!
>>
>> Drweski nicolas wrote:
>>> Do somebody have the tables for a bell-like sound ( by
>>> gen's)
>>> or by additive synthesys. I have seen the propriety
>>> somowhere but I don't remember where.
>>> If you have ther way or making them it will be
>>> helpfull
>>> thanks
>>> Nicolas
>>>
>>>
>>>
>>>
>>> ___________________________________________________________________________ 
>>> Nouveau : téléphonez moins cher avec Yahoo! Messenger ! Découvez les 
>>> tarifs exceptionnels pour appeler la France et l'international.
>>> Téléchargez sur http://fr.messenger.yahoo.com
>> -- 
>> Send bugs reports to this list.
>> To unsubscribe, send email to csound-unsubscribe@lists.bath.ac.uk
> 
> Victor Lazzarini
> Music Technology Laboratory
> Music Department
> National University of Ireland, Maynooth

here is what i have - i think i got it from csoundbook examples

On Thu, 9 Mar 2006, Drweski nicolas wrote:

> Do somebody have the tables for a bell-like sound ( by
> gen's)
> or by additive synthesys. I have seen the propriety
> somowhere but I don't remember where.
> If you have ther way or making them it will be
> helpfull




;;; BELL INSTRUMENT BASED ON RISSET

;;; FIGURE 3.27 FROM DODGE & JERSE, P.94


sr             =         44100

kr             =         441

ksmps          =         100

nchnls         =         1


instr 1


ka1            =         p4

ka2            =         p4*.67

ka3            =         p4

ka4            =         p4*1.8

ka5            =         p4*2.67

ka6            =         p4*1.67

ka7            =         p4*1.46

ka8            =         p4*1.33

ka9            =         p4*1.33

ka10           =         p4

ka11           =         p4*1.33


id1            =         p3

id2            =         p3*.9

id3            =         p3*.65

id4            =         p3*.55

id5            =         p3*.325

id6            =         p3*.35

id7            =         p3*.25

id8            =         p3*.2

id9            =         p3*.15

id10           =         p3*.1

id11           =         p3*.075


kf1            =         p5*.56

kf2            =         p5*.56+1

kf3            =         p5*.92

kf4            =         p5*.92+1.7

kf5            =         p5*1.19

kf6            =         p5*1.7

kf7            =         p5*2

kf8            =         p5*2.74

kf9            =         p5*3

kf10           =         p5*3.76

kf11           =         p5*4.07


kamp1          oscil1i     0, ka1,id1,2

kamp2          oscil1i     0, ka2,id2,2

kamp3          oscil1i     0, ka3,id3,2

kamp4          oscil1i    0,  ka4,id4,2

kamp5          oscil1i     0, ka5,id5,2

kamp6          oscil1i     0, ka6,id6,2

kamp7          oscil1i     0, ka7,id7,2

kamp8          oscil1i     0, ka8,id8,2

kamp9          oscil1i     0, ka9,id9,2

kamp10         oscil1i     0, ka10,id10,2

kamp11         oscil1i     0, ka11,id11,2


asig1          oscil     kamp1,kf1,1

asig2          oscil     kamp2,kf2,1

asig3          oscil     kamp3,kf3,1

asig4          oscil     kamp4,kf4,1

asig5          oscil     kamp5,kf5,1

asig6          oscil     kamp6,kf6,1

asig7          oscil     kamp7,kf7,1

asig8          oscil     kamp8,kf8,1

asig9          oscil     kamp9,kf9,1

asig10         oscil     kamp10,kf10,1

asig11         oscil     kamp11,kf11,1


add1           =         asig1+asig2+asig3+asig4+asig5+asig6

add2           =         asig7+asig8+asig9+asig10+asig11

add            =         add1+add2

aout           =         add

out            aout

endin



;;; SCORE FOR 3.27


f1 0 8192 10 1

f2 0 513 5 1 513 .00097

;inst start length amp freq

;p1 p2 p3   p4 p5

i1 0    20  2000 200

Here's a bell-like sound using modal synthesis.  Changing the pole  
magnitude alters the ring time.

SL




sr = 44100
kr = 4410
ksmps = 10
nchnls = 2

/*  modal synthesis using biquad filters as oscillators */

instr 1

	ipi = 3.1415926
	idenom = sr*0.5

	ipulseSpd = p4
	icps 	= p5
	ipan = p6
	iamp	= p7
	iModes = p8
	

	apulse	mpulse iamp, 0


	kcps	= cpspch( icps )

	; filter gain

	kamp1 = 600
	kamp2 = 1000
	kamp3 = 1000
	kamp4 = 1000
	kamp5 = 1000
	kamp6 = 1000

	; resonance

	krpole1 = 0.99999
	krpole2 = krpole1^2
	krpole3 = krpole1^3
	krpole4 = krpole1^4
	krpole5 = krpole1^5
	krpole6 = krpole1^6

	; modal frequencies

	if (iModes == 1) goto modes1
	if (iModes == 2) goto modes2
	
	modes1:
	kf1	= kcps * 1			;pot lid
	kf2	= kcps * 6.27
	kf3	= kcps * 3.2
	kf4	= kcps * 9.92
	kf5	= kcps * 14.15
	kf6	= kcps * 6.23
	goto nextPart

	modes2:
	kf1 	= kcps * 1			;uniform wood bar
	kf2 	= kcps * 2.572
	kf3 	= kcps * 4.644
	kf4 	= kcps * 6.984
	kf5 	= kcps * 9.723
	kf6 	= kcps * 12.0
	goto nextPart


	nextPart:

	; convert frequency to radian frequency

	ktheta1 = kf1/idenom * ipi
	ktheta2 = kf2/idenom * ipi
	ktheta3 = kf3/idenom * ipi
	ktheta4 = kf4/idenom * ipi
	ktheta5 = kf5/idenom * ipi
	ktheta6 = kf6/idenom * ipi

	; calculate coefficients

	kb11 = -2 * krpole1 * cos(ktheta1)
	kb21 = krpole1 * krpole1
	kb12 = -2 * krpole2 * cos(ktheta2)
	kb22 = krpole2 * krpole2
	kb13 = -2 * krpole3 * cos(ktheta3)
	kb23 = krpole3 * krpole3
	kb14 = -2 * krpole4 * cos(ktheta4)
	kb24 = krpole4 * krpole4
	kb15 = -2 * krpole5 * cos(ktheta5)
	kb25 = krpole5 * krpole5
	kb16 = -2 * krpole6 * cos(ktheta6)
	kb26 = krpole6 * krpole6

	;printk 1, kb11
	;printk 1, kb21

	;  also try setting the -1 coeff. to 0, but be sure to scale down  
the amplitude!

	asin1	biquad  apulse * kamp1, 1, 0, -1, 1, kb11, kb21
      	asin2       biquad  apulse * kamp2, 1, 0, -1, 1, kb12, kb22
      	asin3       biquad  apulse * kamp3, 1, 0, -1, 1, kb13, kb23
      	asin4       biquad  apulse * kamp4, 1, 0, -1, 1, kb14, kb24
      	asin5       biquad  apulse * kamp5, 1, 0, -1, 1, kb15, kb25
      	asin6       biquad  apulse * kamp6, 1, 0, -1, 1, kb16, kb26


	afin	=	(asin1 + asin2 + asin3 + asin4 + asin5 + asin6)

	outs afin * sqrt(p6), afin * sqrt(1-p6)

endin




;ins		st	dur	pulseSpd	pch	pan	amp 	Modes
i1		0	10	0		8.039	0	1	1
i1		0	10	0		8.04	1	1	1
i1		0	10	0		8.041	0.5	1	1

i1		9	.	.		8.039	0	.	2
i1		.	.	.		8.04	1	.	.
i1		.	.	.		8.041	0.5	.	.

e




Version: 3
Render: Real
Ask: Yes
Functions: ioObject
WindowBounds: 726 44 1512 962
Options: -b128 -A -s -m7 -R


ioView background {65535, 64997, 56784}
ioListing {11, 85} {400, 500}
ioGraph {416, 85} {300, 500}
ioSlider {32, 27} {660, 44} 20.000000 2000.000000 91.874001 pitch

This is not exactly what you asked for, but the fmbell opcode also produces
some very nice tones all on its own.  This example is adapted from the
manual:

------------
; fmbell.orc
; instr 1 from manual examples

sr = 44100
kr = 4410
ksmps = 10
nchnls = 1

; simple fmbell example
instr 1
    iamp = p4
    ifreq = p5
    imodindx = p6
    ixfade = p7
    ivdepth = 0.005
    ivrate = 6
    ifn1 = 1
    ifn2 = 1
    ifn3 = 1
    ifn4 = 1
    ivfn = 1
    
    a1 fmbell iamp, ifreq, imodindx, ixfade, ivdepth, ivrate, \
              ifn1, ifn2, ifn3, ifn4, ivfn
    out a1
endin
------------
; fmbell.sco
; Table #1, a sine wave.
f 1 0 32768 10 1

;    dur   amp   freq  modindx xfade
i1 0 3     10000 880   5       5
i1 + .     .     440   5       5
i1 . .     .     .     3       5
i1 . .     .     .     1       5
i1 . .     .     .     0       5
e
------------

And this has even less to do with the original request, but in the spirit of
sharing, I found that I got some interesting sounds by waveshaping the
fmbell opcode:

-------------
; fmbell2.orc
; instr 2 adds waveshaping

; Anthony Kozar
; January 4, 2005

sr = 44100
kr = 4410
ksmps = 10
nchnls = 1

; fmbell with waveshaping by sine function
instr 2
    iamp = p4
    ifreq = p5
    imodindx = p6        ; fm modulation index
    ixfade = p7          ; fm osc cross fade
    ishapeamt = p8       ; amplitude scaler for waveshaping input
    ivdepth = 0.005      ; vibrato depth
    ivrate = 6           ; vibrate rate
    ifn1 = 1
    ifn2 = 1
    ifn3 = 1
    ifn4 = 1
    ivfn = 1
    
    andx fmbell 0.3, ifreq, imodindx, ixfade, ivdepth, ivrate, \
                ifn1, ifn2, ifn3, ifn4, ivfn

    ishapefn = 1
    ixmode = 1            ; normalized index
    ixoff = 0.5           ; table is centered
    iwrap = p9            ; 0 = no wraparound, 1 = wrapping
    a1    tablei ishapeamt*andx, ishapefn, ixmode, ixoff, iwrap
    
    out iamp*a1
endin

-------------
; fmbell2.sco
; Table #1, a sine wave.
f 1 0 32768 10 1

;    dur   amp   freq  modindx xfade shapeamt wrap?
i2 0 3     10000 880   5       5     0.5      0
i2 + .     .     .     .       .     1.0      0
i2 . .     .     .     .       .     1.0      1
i2 . .     .     .     .       .     3.0      0
i2 . .     .     .     .       .     3.0      1
i2 . .     .     .     .       .     5.0      0
i2 . .     .     .     .       .     5.0      1

e
-------------


Anthony Kozar
anthonykozar AT sbcglobal DOT net

Drweski nicolas wrote on 3/9/06 12:19 PM:

> Do somebody have the tables for a bell-like sound ( by
> gen's) or by additive synthesys.

This is a fascinating example.  Very convincing bell tones!

I have to say that modal synthesis is one of the techniques that I know
absolutely nothing about -- in fact, I have never even seen an explanation
of what it is supposed to do.

Searching online turned up a lot of relevant looking material though, so I
plan to look into this :)

Thanks.

Anthony Kozar
anthonykozar AT sbcglobal DOT net


Scott Lindroth wrote on 3/9/06 10:29 PM:

> Here's a bell-like sound using modal synthesis.  Changing the pole
> magnitude alters the ring time.