I've experimented a little bit with making Phase music with Csound back in
the day.  I really only used a few techniques, but they seemed to do the
job.  And as far as the techniques go, they are pretty standard.

When making music with samples, there were two general techniques that I
used.  The first one involves duplicating a sample, and then either
extending it or shortening it.  Then I would loop the both samples.  The
other sample phase trick, if I was lazy and didn't want to duplicate the
sample, would be two loop the same sample twice, with one of the loops
detuned.

As far as pure Csound goes, there was one technique I used above all else
involving placing notes and an envelope into f-tables, then start 2 or more
voices cycling through these tables with different phasor rates.  For
example:





sr     = 44100
kr     = 4410
ksmps  = 10
nchnls = 2

instr 1
	iamp  = p4              ; amplitude
	ipch  = cpspch( p5 )    ; base pitch
	inote = p6              ; table containing notes on a scale
	ienv  = p7              ; envelope table
	irate = p8              ; rate of phasor
	ipan  = p9              ; pan position
	ilen  = ftlen( inote )  ; length of note table

	aclock phasor   irate / ilen
	kclock downsamp aclock

	knotes table  kclock, inote, 1, 0.0, 0
	aenv   table3 aclock * ilen, ienv, 1, 0, 1

	aosc oscil iamp, ipch * 2^(knotes/12), 1, -1
	aosc =     aosc * aenv * 0dbfs

	out aosc * sqrt( 1 - ipan ), aosc * sqrt( ipan ) 
endin




f1 0 65537 10 1 .3 0 0 .1
f2 0 9 -2 0 3 3 2 3 5 -1
f3 0 8193 -7 0 100 1 8092 0

i1 0 240 0.5 8.02 2 3 4      0.1
i1 0 .   .   .    . . 4.0625 0.9

e




Also, one of my earliest Csound compositions was based on phase.  You can
download it listen to it if you'd like, along with the phase example from
above:

http://www.thumbuki.com/csound/files/mailinglist/MessageFromAnotherPlanet.csd
http://www.thumbuki.com/csound/files/mailinglist/phase.csd

Now I'm inspired.  :)  Wonderful topic.  I wish there were more messages
like this on the list.

Best, 
Jake 

---- 
The Csound Blog 
http://www.thumbuki.com/csound/blog  







David Akbari wrote:
> 
> What are some other ways to generate phase music using Csound? I know
> people have mentioned the use of the 'b' operator in the score... how
> would that work?
> ...
> -David
> 

-- 
View this message in context: http://www.nabble.com/OT%3A-Phase-music-tf4877061.html#a13976923
Sent from the Csound - General mailing list archive at Nabble.com.