A trick.
We create an empty soundfile, for example with SoX

# 4 seconds, stereo, sr=44100, 24bit
sox -n -r44100 -c2 -3 dummy.wav trim 0 4

and

<CsoundSynthesizer>
<CsOptions>
-d -odac
</CsOptions>
<CsInstruments>
sr     = 44100
ksmps  = 64
nchnls = 2
0dbfs  = 1

gilen = 4 * 2 * sr   ; 4 seconds, stereo

opcode tablewsa,0,aaai
  al, ar, andx, ifn xin
  andx0 = andx << 1
  tablew al, andx0, ifn
  tablew ar, andx0 + 1, ifn
endop

instr 1
  al oscils 0.7, 440, 1
  ar oscils 0.7, 880, 1
  andx line 0, p3, gilen/2
  tablewsa al, ar, andx, 2
endin

instr 2
  aamp = 0.7
  al, ar lposcilsa aamp, 1, 0, gilen, 2
  outs al, ar
endin
</CsInstruments>
<CsScore>
f1 0 8192 10 1
f2 0 [4*2*@44100] 1 "dummy.wav" 0 0 0
i1 0 4
i2 0 4
e
</CsScore>
</CsoundSynthesizer>

tito

On Sat, Dec 31, 2011 at 12:54:45AM -0500, Kelly Hirai wrote:
> hey all,
> got a korg kontrol a couple of days ago, and i'm set on writing a stereo
> looper for it.
> 
> id like to write stereo audio to a table in real time that lposcilsa can
> access, but i can't find anything that can write that kind of table
> other than gen01. do i have to use 2 lposcil and 2 tables or is there a
> kind of  tablewsa out there?
> 
> kelly


Send bugs reports to the Sourceforge bug tracker
            https://sourceforge.net/tracker/?group_id=81968&atid=564599
Discussions of bugs and features can be posted here
To unsubscribe, send email sympa@lists.bath.ac.uk with body "unsubscribe csound"