Michele, here is an extreme example, inspired by Miller Puckette's Pd
B14.sampler.rockafella.pd. It's complex but very instructive.

You have tried sndwarp(st)? It's a granular time stretcher and/or
pitchshifter that uses a GEN01.

<CsoundSynthesizer>
<CsInstruments>
  sr	 = 44100
  ksmps	 = 10
  nchnls = 2

instr 1
  iamp        = ampdb(p4)
  itransp     = powoftwo(p5/120)  ; p5 is halftones/10
  ichunk      = p6*0.001
  iprecession = p7*0.01
  ilooplen    = p8*0.001          ; p8 in msec

  achunk       oscili ichunk, 1/p3, 2
  aprecession  oscili iprecession, 1/p3, 3
  alooplen     oscili ilooplen, 1/p3, 4
  atransp      oscili itransp, 1/p3, 5
  afrq = (atransp-aprecession) / achunk

  aphs1	phasor afrq                    ; phasor 1
  aphs2	wrap aphs1+0.5, 0, 1           ; phasor 2
  aphs3	phasor aprecession / alooplen  ; phasor for the read position
  areadpt = aphs3*alooplen             ; read position

  atrig1 diff -aphs1   ; trigger 1
  atrig2 diff -aphs2   ; trigger 2

  achunk1 samphold achunk, atrig1
  achunk2 samphold achunk, atrig2

  ;; cos envs in sync
  aenv1	= iamp*cos((aphs1-0.5)*$M_PI)
  aenv2	= iamp*cos((aphs2-0.5)*$M_PI)

  ;; table lookup
  a1 table3 (achunk1*aphs1+areadpt)*sr, 1
  a2 table3 (achunk2*aphs2+areadpt)*sr, 1

  aout	butterhp a1*aenv1+a2*aenv2, 5

  outs aout, aout

endin
</CsInstruments>
<CsScore>
f1	0	[@44100]	1	"voice.wav" 0 0 0 
;; chunk size
f2	0	8	7	.25 3 .25 3 1 2 .25 
;; precession
f3	0	8	7	0 8 1
;; loop length
f4	0	8	7	1 2 1 4 0.25 2 1
;; trasposition
f5	0	8	7	0 5 50 2 -50 1 0

;;                      amp     transp  chunk   prec    looplen
i1	0	60	80	1	100	100	900	
e
</CsScore>
</CsoundSynthesizer>

tito

On Sat, Nov 19, 2011 at 03:48:39PM +0000, Victor Lazzarini wrote:
> But will not do timestretching.
> On 19 Nov 2011, at 14:04, k_o_m_p wrote:
> 
> > If you prefer you could also use a table with phasor. With some maths it would do what you want.
> > Luis
> > 
> > Am 19.11.11 12:40, schrieb Iain McCurdy:
> >> As Victor says, you can achieve what you describe using mincer and can then modulate the loop start and end points during performance if you like. If you really prefer to edit the audio stored in the function table you can still do this also. You can then loop and timestretch the whole function table using something like temposcal, as below.
> >> instr 1iloopstart = 1;(in seconds)iloopend = 2ktimescal = 1 ;time scaling factorifile	ftgen  0,0,-(iloopend-iloopstart)*sr,1,"soundfile.wav",iloopstart,0,1idur = iloopend-iloopstarta1 temposcal ktimescal, 0.1, 1, ifile, 0out a1endin
> >> Iain
> >>> From: Victor.Lazzarini@nuim.ie
> >>> To: csound@lists.bath.ac.uk
> >>> Date: Sat, 19 Nov 2011 11:27:07 +0000
> >>> Subject: Re: [Csnd] set different start and stop playing a file
> >>> 
> >>> Minced does exactly that , all you need to do is control its read position to start end or loop the playback
> >>> 
> >>> 
> >>> 
> >>> 
> > 
> > -- 
> > --
> > http://luisantunespena.eu
> > 
> > 
> > 
> > Send bugs reports to the Sourceforge bug tracker
> >           https://sourceforge.net/tracker/?group_id=81968&atid=564599
> > Discussions of bugs and features can be posted here
> > To unsubscribe, send email sympa@lists.bath.ac.uk with body "unsubscribe csound"
> > 
> 
> Dr Victor Lazzarini
> Senior Lecturer
> Dept. of Music
> NUI Maynooth Ireland
> tel.: +353 1 708 3545
> Victor dot Lazzarini AT nuim dot ie
> 
> 
> 
> 
> 
> Send bugs reports to the Sourceforge bug tracker
>             https://sourceforge.net/tracker/?group_id=81968&atid=564599
> Discussions of bugs and features can be posted here
> To unsubscribe, send email sympa@lists.bath.ac.uk with body "unsubscribe csound"
> 


Send bugs reports to the Sourceforge bug tracker
            https://sourceforge.net/tracker/?group_id=81968&atid=564599
Discussions of bugs and features can be posted here
To unsubscribe, send email sympa@lists.bath.ac.uk with body "unsubscribe csound"