Hi All, I have written the code for #ifdef #else #end,
to be able to use my instruments with the new parser.
If it can be useful, I send the patch.

The following test is ok

<CsoundSynthesizer>
<CsInstruments>

#ifdef PARSER_TEST
prints "=== THE PARSER WORKS ===\n"
  #ifndef SKIP_NEWS
    prints "=== NOTE: white spaces before #ifdef; error with old parser\n"
    #ifndef APPLY_LP
      prints "welcome high frequencies"      
    #else
      #include "lp.flt"
    #end
  #endif    ; #end or #endif
#define FREQ #1000#
#define AMP  #15000#
#else
prints "=== E L S E ===\n"
opcode oscilzzz,a,iii
  iamp,ifrq,ifn xin
  andx randh 1, ifrq
  aout table andx, ifn, 1
  xout aout*iamp
endop
#define FREQ #440#
#define AMP  #10000#
#end

instr 1

#ifndef GO_INSANE
  #ifdef HQ
    #define FSIZE #65536#
    #define OSCIL #poscil3#
  #else
    #define OSCIL #oscili#
  #end
#else
  #ifdef PARSER_TEST
    #define OSCIL #oscil#
  #else
    #define OSCIL #oscilzzz#
  #end
  prints "\033[31;1mplease don't put your wires in my brain\n"
#end

#ifndef FSIZE
#define FSIZE #1024#
#end

  iwave ftgen 1, 0, $FSIZE, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1
  aout $OSCIL $AMP, $FREQ, 1
  #ifdef LP
  aout $LP aout
  #end
  out aout

endin

</CsInstruments>
<CsScore>
i1 0 1
</CsScore>
</CsoundSynthesizer>


;; lp.flt
#ifndef LP
opcode lp,a,a
  ain xin
  aout delay1 ain
  xout (ain+aout)*0.5
endop
#define LP #lp#
#end


tito

------------------------------------------------------------------------------
All the data continuously generated in your IT infrastructure 
contains a definitive record of customers, application performance, 
security threats, fraudulent activity, and more. Splunk takes this 
data and makes sense of it. IT sense. And common sense.
http://p.sf.net/sfu/splunk-novd2d
_______________________________________________
Csound-devel mailing list
Csound-devel@lists.sourceforge.net